split home-manager into their own submodules

modules/dev/javascript/common.nix

@@ -0,0 +1,25 @@
+{ pkgs }:
+let
+  packages = builtins.attrValues {
+    inherit (pkgs) nodejs;
+    inherit (pkgs.nodePackages) pnpm;
+  };
+in
+{
+  inherit packages;
+  devShell = pkgs.mkShell {
+    inherit packages;
+    name = "javascript-dev-shell";
+    shellHook = ''
+      echo "📦 JavaScript dev environment"
+    '';
+  };
+  sessionVariables = {
+    NPM_CONFIG_USERCONFIG = "\${XDG_CONFIG_HOME}/npm/npmrc";
+    PNPM_HOME = "\${XDG_DATA_HOME}/pnpm";
+  };
+  sessionPath = [
+    "\${XDG_DATA_HOME}/npm/bin"
+    "\${XDG_DATA_HOME}/pnpm"
+  ];
+}

modules/dev/javascript/home.nix

@@ -0,0 +1,43 @@
+{
+  config,
+  inputs,
+  lib,
+  osConfig ? null,
+  pkgs,
+  ...
+}:
+let
+  hm = inputs.self.lib.hmModule {
+    inherit
+      config
+      inputs
+      osConfig
+      ;
+    optionPath = [
+      "dev"
+      "javascript"
+    ];
+  };
+  cfg = config.my.dev.javascript;
+  javascript = import ./common.nix { inherit pkgs; };
+in
+{
+  options.my.dev.javascript.enable = lib.mkEnableOption "Install JavaScript tooling globally";
+  config = lib.mkMerge [
+    {
+      my.dev.javascript.enable = lib.mkDefault hm.enabledByDefault;
+    }
+    (lib.mkIf cfg.enable {
+      home.packages = javascript.packages;
+      xdg.configFile = {
+        "npm/npmrc".source = ../../../dotfiles/npmrc;
+        "configstore/update-notifier-npm-check.json".text = builtins.toJSON {
+          optOut = false;
+          lastUpdateCheck = 1646662583446;
+        };
+      };
+      home.sessionVariables = javascript.sessionVariables;
+      home.sessionPath = javascript.sessionPath;
+    })
+  ];
+}

modules/dev/javascript/nixos.nix

@@ -0,0 +1,27 @@
+{
+  config,
+  inputs,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  javascript = import ./common.nix { inherit pkgs; };
+in
+{
+  options = {
+    my.dev.javascript = {
+      enable = lib.mkEnableOption "Install JavaScript tooling globally";
+      users = lib.mkOption {
+        type = inputs.self.lib.usersOptionType lib;
+        default = config.my.toggleUsers.dev;
+        description = "Users to install JavaScript packages for";
+      };
+    };
+    devShells.javascript = lib.mkOption {
+      type = lib.types.package;
+      default = javascript.devShell;
+      description = "JavaScript/Node development shell with npm/pnpm support";
+    };
+  };
+}