probably broken, car ride modularizing

pkgs/obs-studio.nix

@@ -0,0 +1,49 @@
+{
+  pkgs,
+  lib,
+  config,
+  ...
+}:
+
+with lib;
+
+let
+  cfg = config.programs.obs-studio;
+in
+{
+  options.programs.obs-studio = {
+    enable = mkEnableOption "OBS Studio program";
+
+    package = mkOption {
+      type = types.package;
+      default = pkgs.obs-studio;
+      defaultText = "pkgs.obs-studio";
+      description = "Set obs-studio package to use.";
+    };
+
+    enableVirtualCamera = mkOption {
+      type = types.bool;
+      default = false;
+      description = ''
+        Installs and sets up the v4l2loopback kernel module, necesary for OBS
+        to start a virtual camera.
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    environment.systemPackages = [ cfg.package ];
+
+    boot = mkIf cfg.enableVirtualCamera {
+      extraModulePackages = with config.boot.kernelPackages; [ v4l2loopback ];
+
+      extraModprobeConfig = ''
+        options v4l2loopback devices=1 video_nr=1 card_label="OBS Cam" exclusive_caps=1
+      '';
+    };
+
+    security.polkit.enable = mkIf cfg.enableVirtualCamera true;
+  };
+
+  meta.maintainers = with lib.maintainers; [ CaptainJawZ ];
+}