masive rewriting and setup of server files

pkgs/mealie-service.nix

@@ -0,0 +1,82 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  cfg = config.services.mealie;
+  pkg = cfg.package;
+in
+{
+  options.services.mealie = {
+    enable = lib.mkEnableOption "Mealie, a recipe manager and meal planner";
+
+    package = lib.mkPackageOption pkgs "mealie" { };
+
+    listenAddress = lib.mkOption {
+      type = lib.types.str;
+      default = "0.0.0.0";
+      description = "Address on which the service should listen.";
+    };
+
+    port = lib.mkOption {
+      type = lib.types.port;
+      default = 9000;
+      description = "Port on which to serve the Mealie service.";
+    };
+
+    settings = lib.mkOption {
+      type = with lib.types; attrsOf anything;
+      default = { };
+      description = ''
+        Configuration of the Mealie service.
+
+        See [the mealie documentation](https://nightly.mealie.io/documentation/getting-started/installation/backend-config/) for available options and default values.
+      '';
+      example = {
+        ALLOW_SIGNUP = "false";
+      };
+    };
+
+    credentialsFile = lib.mkOption {
+      type = with lib.types; nullOr path;
+      default = null;
+      example = "/run/secrets/mealie-credentials.env";
+      description = ''
+        File containing credentials used in mealie such as {env}`POSTGRES_PASSWORD`
+        or sensitive LDAP options.
+
+        Expects the format of an `EnvironmentFile=`, as described by {manpage}`systemd.exec(5)`.
+      '';
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    systemd.services.mealie = {
+      description = "Mealie, a self hosted recipe manager and meal planner";
+
+      after = [ "network-online.target" ];
+      wants = [ "network-online.target" ];
+      wantedBy = [ "multi-user.target" ];
+
+      environment = {
+        PRODUCTION = "true";
+        API_PORT = toString cfg.port;
+        BASE_URL = "http://localhost:${toString cfg.port}";
+        DATA_DIR = "/var/lib/mealie";
+        CRF_MODEL_PATH = "/var/lib/mealie/model.crfmodel";
+      } // (builtins.mapAttrs (_: toString) cfg.settings);
+
+      serviceConfig = {
+        DynamicUser = true;
+        User = "mealie";
+        ExecStartPre = "${pkg}/libexec/init_db";
+        ExecStart = "${lib.getExe pkg} -b ${cfg.listenAddress}:${builtins.toString cfg.port}";
+        EnvironmentFile = lib.mkIf (cfg.credentialsFile != null) cfg.credentialsFile;
+        StateDirectory = "mealie";
+        StandardOutput = "journal";
+      };
+    };
+  };
+}

pkgs/obs-studio.nix

@@ -40,7 +40,7 @@ in
 
   config = lib.mkIf cfg.enable {
     programs.obs-studio.finalPackage = pkgs.wrapOBS.override { obs-studio = cfg.package; } {
-      plugins = cfg.plugins;
+      inherit (cfg) plugins;
     };
 
     environment.systemPackages = [ cfg.finalPackage ];

pkgs/shiori-service.nix

@@ -4,7 +4,6 @@
   pkgs,
   ...
 }:
-
 let
   cfg = config.services.shiori;
 in

pkgs/shiori/shiori.nix

@@ -1,43 +0,0 @@
-{
-  lib,
-  buildGoModule,
-  fetchFromGitHub,
-  installShellFiles,
-}:
-
-buildGoModule rec {
-  pname = "shiori";
-  version = "1.7.0";
-
-  vendorHash = "sha256-fakRqgoEcdzw9WZuubaxfGfvVrMvb8gV/IwPikMnfRQ=";
-
-  doCheck = false;
-
-  src = fetchFromGitHub {
-    owner = "go-shiori";
-    repo = pname;
-    rev = "v${version}";
-    sha256 = "sha256-5+hTtvBnj3Nh5HitReVkLift9LTiMYVuuYx5EirN0SA=";
-  };
-
-  nativeBuildInputs = [ installShellFiles ];
-  postInstall = ''
-    installShellCompletion --cmd shiori \
-      --bash <($out/bin/shiori completion bash) \
-      --fish <($out/bin/shiori completion fish) \
-      --zsh <($out/bin/shiori completion zsh)
-  '';
-
-  # passthru.tests.smoke-test = nixosTests.shiori; # test broken
-
-  meta = with lib; {
-    description = "Simple bookmark manager built with Go";
-    mainProgram = "shiori";
-    homepage = "https://github.com/go-shiori/shiori";
-    license = licenses.mit;
-    maintainers = with maintainers; [
-      minijackson
-      CaptainJawZ
-    ];
-  };
-}