rest of the split migration

modules/dev/mcp/common.nix

@@ -0,0 +1,18 @@
+{ pkgs, inputs }:
+let
+  packages = [
+    pkgs.codex
+    inputs.self.packages.${pkgs.system}.nixos-mcp
+  ];
+in
+{
+  inherit packages;
+  devShell = pkgs.mkShell {
+    inherit packages;
+    name = "mcp-dev-shell";
+    shellHook = ''
+      export CODEX_HOME=$PWD/.codex
+      echo "MCP shell ready: codex + nixos-mcp"
+    '';
+  };
+}

modules/dev/mcp/home.nix

@@ -0,0 +1,34 @@
+{
+  config,
+  inputs,
+  lib,
+  osConfig ? null,
+  pkgs,
+  ...
+}:
+let
+  hm = inputs.self.lib.hmModule {
+    inherit
+      config
+      inputs
+      osConfig
+      ;
+    optionPath = [
+      "dev"
+      "mcp"
+    ];
+  };
+  cfg = config.my.dev.mcp;
+  feature = import ./common.nix { inherit pkgs inputs; };
+in
+{
+  options.my.dev.mcp.enable = lib.mkEnableOption "Install MCP tooling globally";
+  config = lib.mkMerge [
+    {
+      my.dev.mcp.enable = lib.mkDefault hm.enabledByDefault;
+    }
+    (lib.mkIf cfg.enable {
+      home.packages = feature.packages;
+    })
+  ];
+}

modules/dev/mcp/nixos.nix

@@ -0,0 +1,27 @@
+{
+  config,
+  inputs,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  feature = import ./common.nix { inherit pkgs inputs; };
+in
+{
+  options = {
+    my.dev.mcp = {
+      enable = lib.mkEnableOption "Install MCP tooling globally";
+      users = lib.mkOption {
+        type = inputs.self.lib.usersOptionType lib;
+        default = config.my.toggleUsers.dev;
+        description = "Users to install MCP packages for";
+      };
+    };
+    devShells.mcp = lib.mkOption {
+      type = lib.types.package;
+      default = feature.devShell;
+      description = "MCP dev shell for this repo";
+    };
+  };
+}