moved gitea runners

modules/nix/gitea-actions-runners/nixos.nix

@@ -0,0 +1,32 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+let
+  cfg = config.my.servers.gitea;
+in
+{
+  config = lib.mkIf (cfg.enable && config.my.secureHost) {
+    services.gitea-actions-runner.instances.nixos = {
+      inherit (cfg) url enable;
+      name = "${config.networking.hostName}-nixos";
+      tokenFile = config.sops.secrets.gitea.path;
+      labels = [
+        "nixos:host"
+      ];
+      hostPackages = builtins.attrValues {
+        inherit (pkgs)
+          bash
+          coreutils
+          gitMinimal
+          nix
+          attic-client
+          nodejs # Required for GitHub Actions
+          openssh # Required for SSH git operations
+          ;
+      };
+    };
+  };
+}

modules/nix/gitea-actions-runners/ryujinx.nix

@@ -0,0 +1,59 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+let
+  cfg = config.my.servers.gitea;
+in
+{
+  config = lib.mkIf (cfg.enable && config.my.secureHost) {
+    services.gitea-actions-runner.instances.ryujinx = {
+      inherit (cfg) url enable;
+      name = "${config.networking.hostName}-ryujinx";
+      tokenFile = config.sops.secrets.gitea.path;
+      labels = [
+        "ubuntu-latest:host"
+        "ubuntu-20.04:host"
+      ];
+      hostPackages =
+        let
+          python3 = pkgs.python3.withPackages (
+            ps:
+            builtins.attrValues {
+              inherit (ps)
+                pyyaml
+                lxml
+                ;
+            }
+          );
+        in
+        builtins.attrValues {
+          inherit python3;
+          inherit (pkgs.xorg) libX11;
+          inherit (pkgs)
+            bash
+            coreutils
+            curl
+            gawk
+            gitMinimal
+            gnused
+            nodejs
+            wget
+            gnutar
+            gzip
+            dotnet-sdk_8
+            openal
+            vulkan-loader
+            libGL
+            gtk3
+            llvm_15
+            rcodesign
+            gh
+            p7zip
+            ;
+        };
+    };
+  };
+}