gitea nixos cicd

2025-09-27 21:04:50 -06:00
parent 0b709f4ef0
commit e6c9e80a3b
6 changed files with 216 additions and 67 deletions
--- a/modules/servers/gitea-actions-runners/ryujinx.nix
+++ b/modules/servers/gitea-actions-runners/ryujinx.nix
@@ -0,0 +1,60 @@
+{
+  lib,
+  config,
+  pkgs,
+  ...
+}:
+let
+  cfg = config.my.servers.gitea;
+in
+{
+  config = lib.mkIf cfg.enable {
+    services.gitea-actions-runner.instances.ryujinx = {
+      enable = true;
+      url = cfg.url;
+      name = "${config.networking.hostName}-ryujinx";
+      tokenFile = config.sops.secrets.gitea.path;
+      labels = [
+        "ubuntu-latest:host"
+        "ubuntu-20.04:host"
+      ];
+      hostPackages =
+        let
+          python3 = pkgs.python3.withPackages (
+            ps:
+            builtins.attrValues {
+              inherit (ps)
+                pyyaml
+                lxml
+                ;
+            }
+          );
+        in
+        builtins.attrValues {
+          inherit python3;
+          inherit (pkgs)
+            bash
+            coreutils
+            curl
+            gawk
+            gitMinimal
+            gnused
+            nodejs
+            wget
+            gnutar
+            gzip
+            dotnet-sdk_8
+            openal
+            vulkan-loader
+            libGL
+            gtk3
+            llvm_15
+            rcodesign
+            gh
+            p7zip
+            ;
+          inherit (pkgs.xorg) libX11;
+        };
+    };
+  };
+}