{
  description = "A very basic flake";

  inputs = {
    # lix = {
    #   url =
    #     "git+https://git@git.lix.systems/lix-project/lix?ref=refs/tags/2.90-beta.1";
    #   flake = false;
    # };
    # lix-module = {
    #   url = "git+https://git.lix.systems/lix-project/nixos-module";
    #   inputs.lix.follows = "lix";
    #   inputs.nixpkgs.follows = "nixpkgs";
    # };
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-23.11";
    nixpkgs-unstable.url = "github:nixos/nixpkgs?ref=nixos-unstable";
    home-manager.url = "github:nix-community/home-manager/release-23.11";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = { self, nixpkgs, nixpkgs-unstable, home-manager, ... }@inputs:
    let
      inherit (self) outputs;
      lib = nixpkgs.lib // home-manager.lib;
      system = "x86_64-linux";
      makePkgs = repo:
        import repo {
          inherit system;
          config.allowUnfree = true;
        };
      pkgs = makePkgs nixpkgs;
      pkgsU = makePkgs nixpkgs-unstable;
    in {
      inherit lib pkgs;
      formatter = pkgs.alejandra;
      nixosConfigurations = {
        workstation = lib.nixosSystem {
          inherit system;
          modules = [
            # lix-module.nixosModules.default
            ./hosts/workstation/configuration.nix
            ({ pkgs, ... }: {
              nixpkgs.overlays = [
                (self: super: {
                  planify = pkgsU.planify;
                  gdtoolkit = pkgsU.gdtoolkit;
                  gallery-dl = pkgsU.gallery-dl;
                  lutris = super.lutris.override {
                    extraPkgs = pkgs: [
                      pkgs.winetricks
                      pkgs.wine64Packages.stable
                      pkgs.wineWowPackages.stable
                    ];
                  };
                  nerdfonts = super.nerdfonts.override {
                    fonts = [ "CascadiaCode" "ComicShannsMono" "Iosevka" ];
                  };
                  handbrake = super.handbrake.override { useGtk = true; };
                  discord = super.discord.override { withOpenASAR = true; };
                  ripgrep = super.ripgrep.override { withPCRE2 = true; };
                  blender = super.blender.override { cudaSupport = true; };
                })
              ];
            })
          ];
          specialArgs = { inherit inputs outputs; };
        };
      };
    };
}