{
  config,
  lib,
  pkgs,
  ...
}:
let
  krisp-patcher =
    pkgs.writers.writePython3Bin "krisp-patcher"
      {
        libraries = builtins.attrValues {
          inherit (pkgs.python3Packages)
            capstone
            pyelftools
            ;
        };
        flakeIgnore = [
          "E501" # line too long (82 > 79 characters)
          "F403" # 'from module import *' used; unable to detect undefined names
          "F405" # name may be undefined, or defined from star imports: module
        ];
      }
      (
        builtins.readFile (
          pkgs.fetchurl {
            url = "https://pastebin.com/raw/8tQDsMVd";
            sha256 = "sha256-IdXv0MfRG1/1pAAwHLS2+1NESFEz2uXrbSdvU9OvdJ8=";
          }
        )
      );
in
{
  options.my.apps.internet.enable = lib.mkEnableOption "enable";
  config = lib.mkIf config.my.apps.internet.enable {
    home-manager.users.jawz.programs.librewolf = import ./librewolf.nix;
    programs.geary.enable = true;
    users.users.jawz.packages = builtins.attrValues {
      # inherit (inputs.zen-browser.packages.x86_64-linux) twilight;
      inherit krisp-patcher;
      inherit (pkgs)
        # thunderbird # email client
        warp # transfer files with based ppl
        brave # crypto-browser that at least somewhat integrates with gtk
        nextcloud-client # self-hosted google-drive alternative
        fragments # beautiful torrent client
        tor-browser-bundle-bin # dark web, so dark!
        telegram-desktop # furry chat
        nicotine-plus # remember Ares?
        discord # :3
        vdhcoapp # video download helper assistant
        nextcloud-talk-desktop # nextcloud talk client
        fractal # matrix client
        ;
    };
  };
}