{
  mkpkgs,
  inputs,
  ...
}:
let
  pkgs = mkpkgs inputs.nixpkgs;
  pkgsU = mkpkgs inputs.nixpkgs-unstable;
in
final: prev:
let
  jawzScriptsSrc = inputs.jawz-scripts;
in
{
  handbrake = prev.handbrake.override { useGtk = true; };
  ripgrep = prev.ripgrep.override { withPCRE2 = true; };
  blender = prev.blender.override { cudaSupport = true; };
  sunshine = prev.sunshine.override { cudaSupport = true; };
  obs-studio = prev.obs-studio.override { cudaSupport = true; };
  nautilus = prev.nautilus.overrideAttrs (old: {
    buildInputs =
      old.buildInputs
      ++ builtins.attrValues {
        inherit (pkgs.gst_all_1)
          gst-plugins-good
          gst-plugins-bad
          ;
      };
  });
  lutris = prev.lutris.override {
    extraPkgs =
      pkgs:
      builtins.attrValues {
        inherit (pkgs) pango winetricks;
      }
      ++ (with pkgs; [
        wine64Packages.stable
        wineWowPackages.stable
      ]);
  };
  discord = prev.discord.override {
    withVencord = true;
    withOpenASAR = true;
  };
  waybar = prev.waybar.overrideAttrs (old: {
    mesonFlags = old.mesonFlags ++ [ "-Dexperimental=true" ];
  });
  qbittorrent = prev.qbittorrent.overrideAttrs (_old: rec {
    version = "5.1.3";
    src = prev.fetchFromGitHub {
      owner = "qbittorrent";
      repo = "qBittorrent";
      rev = "release-${version}";
      hash = "sha256-RIItbrpkMFglO2NwbgpBhgBSk5+vdywatGVwnbWkNVQ=";
    };
  });
  python3Packages = prev.python3Packages.override {
    overrides = pyfinal: _pyprev: {
      webcomix = prev.python3Packages.callPackage "${jawzScriptsSrc}/pkgs_pr/webcomix.nix" { };
      download = prev.python3Packages.callPackage "${jawzScriptsSrc}/pkgs/download.nix" {
        gallery-dl = final.gallery-dl-dev;
        webcomix = pyfinal.webcomix;
      };
    };
  };
  gallery-dl-dev = prev.gallery-dl.overrideAttrs (_old: {
    version = "unstable";
    src = inputs.gallery-dl-src;
    meta = prev.gallery-dl.meta // {
      homepage = "https://github.com/mikf/gallery-dl";
    };
  });
  gallery-dl = final.gallery-dl-dev;
  download = final.python3Packages.download;
  inherit (pkgsU)
    code-cursor
    symbola
    mealie
    flaresolver
    deadnix
    sillytavern
    open-webui
    codex
    ;
}