{
  mkpkgs,
  inputs,
  ...
}:
let
  pkgs = mkpkgs inputs.nixpkgs;
in
_final: prev: {
  nautilus = prev.nautilus.overrideAttrs (old: {
    buildInputs =
      old.buildInputs
      ++ builtins.attrValues {
        inherit (pkgs.gst_all_1)
          gst-plugins-good
          gst-plugins-bad
          ;
      };
  });
  celluloid = prev.celluloid.overrideAttrs (old: {
    patches = (old.patches or [ ]) ++ [
      (builtins.fetchurl {
        url = "https://github.com/celluloid-player/celluloid/commit/b9004ea88629e61fec19e40c74ebd137d75ebcf8.patch";
        sha256 = "1np330y9i5hwmm472d5bcw06xz7c2xy6amdakh4fa2kkhqh68377";
      })
      (builtins.fetchurl {
        url = "https://github.com/celluloid-player/celluloid/commit/85d6c6cc478bac4bdd0b32757c31549171efb8b4.patch";
        sha256 = "09r0avh60zx9nd1zxmw8538ir3617vgigk0hxzgqv8rld1ipiq2q";
      })
      (builtins.fetchurl {
        url = "https://github.com/celluloid-player/celluloid/commit/9267da8c907834d74f92970b66dea2ce30904408.patch";
        sha256 = "0syxz21y93s5s33i85k57nalf9ch1ynw3k8ifbzfii8aijpqflf9";
      })
    ];
  });
  lutris = prev.lutris.override {
    extraPkgs =
      pkgs:
      builtins.attrValues {
        inherit (pkgs) pango winetricks;
      }
      ++ (with pkgs; [
        wine64Packages.stable
        wineWowPackages.stable
      ]);
  };
  handbrake = prev.handbrake.override { useGtk = true; };
  ripgrep = prev.ripgrep.override { withPCRE2 = true; };
  papirus-icon-theme = prev.papirus-icon-theme.override { color = "orange"; };
  discord = prev.discord.override {
    withVencord = true;
    withOpenASAR = true;
  };
}