{ lib, config, ... }:
let
  cfg = config.my.servers.audiobookshelf;
  setup = import ./setup.nix { inherit lib config; };
in
{
  options.my.servers.audiobookshelf = setup.mkOptions "audiobookshelf" "audiobooks" 5687;
  config = {
    # always opening port to upload books
    networking.firewall.allowedTCPPorts = [ cfg.port ];
    services = {
      audiobookshelf = lib.mkIf cfg.enable {
        inherit (cfg) port;
        enable = true;
        group = "piracy";
      };
      nginx.virtualHosts."${cfg.host}" = lib.mkIf cfg.enableProxy (
        setup.proxy {
          "/" = {
            proxyPass = cfg.local;
            extraConfig = ''
              proxy_set_header X-Forwarded-For   $proxy_add_x_forwarded_for;
              proxy_set_header X-Forwarded-Proto $scheme;
              proxy_set_header Host              $host;
              proxy_set_header Upgrade           $http_upgrade;
              proxy_set_header Connection        "upgrade";
              proxy_http_version                 1.1;
              proxy_redirect                     http:// https://;
            '';
          };
        }
      );
    };
  };
}