{ pkgs }:
_final: prev: {
  gnome = prev.gnome.overrideScope (
    _final: prev: {
      nautilus = prev.nautilus.overrideAttrs (old: {
        buildInputs =
          old.buildInputs
          ++ builtins.attrValues {
            inherit (pkgs.gst_all_1)
              gst-plugins-good
              gst-plugins-bad
              ;
          };
      });
    }
  );
  lutris = prev.lutris.override {
    extraPkgs =
      pkgs:
      builtins.attrValues {
        inherit (pkgs) pango winetricks;
      }
      ++ (with pkgs; [
        wine64Packages.stable
        wineWowPackages.stable
      ]);
  };
  homepage-dashboard = prev.homepage-dashboard.overrideAttrs (old: rec {
    version = "0.9.12";
    src = pkgs.fetchFromGitHub {
      owner = "gethomepage";
      repo = "homepage";
      rev = "v${version}";
      hash = "sha256-/7MWeCn9vMRlwqYoOf0oldtb1hy0xyKI4+HvnUQIU1c=";
    };
  });
  handbrake = prev.handbrake.override { useGtk = true; };
  discord-ptb = prev.discord.override { withVencord = true; };
  ripgrep = prev.ripgrep.override { withPCRE2 = true; };
  papirus-icon-theme = prev.papirus-icon-theme.override { color = "yellow"; };
  blender = prev.blender.override { cudaSupport = true; };
}