# Do not modify this file!  It was generated by ‘nixos-generate-config’
# and may be overwritten by future invocations.  Please make changes
# to /etc/nixos/configuration.nix instead.
{ config, lib, pkgs, modulesPath, ... }:

let
  localhost = "127.0.0.1";
  jellyfinPort = "8096";
  radarrPort = 7878;
  newflixPort = 8897;
  shioriPort = 9001;
  flamePort = 5005;
  secretFlamePort = 5007;
  lidarrPort = 8686;
  bazarrPort = 6767;
  sonarrPort = 8989;
  prowlarrPort = 9696;
  vaultPort = 9666;
  searxPort = 8080;
  kavitaPort = 5000;
  nextcloudPort = 80;
in {
  services.nginx = {
    enable = true;
    recommendedTlsSettings = true;
    recommendedGzipSettings = true;
    recommendedOptimisation = true;
    # recommendedProxySettings = true;
    sslCiphers = "AES256+EECDH:AES256+EDH:!aNULL";
    appendHttpConfig = ''
      ### GLOBAL
        # Add HSTS header with preloading to HTTPS requests.
        # Adding this header to HTTP requests is discouraged
        map $scheme $hsts_header {
            https   "max-age=31536000; includeSubdomains; preload";
        }
        add_header Strict-Transport-Security $hsts_header;

        # Enable CSP for your services.
        #add_header Content-Security-Policy "script-src 'self'; object-src 'none'; base-uri 'none';" always;

        # Minimize information leaked to other domains
        add_header 'Referrer-Policy' 'origin-when-cross-origin';

        # Disable embedding as a frame
        # add_header X-Frame-Options DENY;

        # Prevent injection of code in other mime types (XSS Attacks)
        add_header X-Content-Type-Options nosniff;

        # Enable XSS protection of the browser.
        # May be unnecessary when CSP is configured properly (see above)
        add_header X-XSS-Protection "1; mode=block";

        # This might create errors
        proxy_cookie_path / "/; secure; HttpOnly; SameSite=strict";
        # NEXTCLOUD
        # upstream php-handler {
        #   server ${localhost}:9000;
        #   #server unix:/var/run/php/php7.4-fpm.sock;
        # }

        # Set the `immutable` cache control options only for assets with a cache busting `v` argument
        #   map $arg_v $asset_immutable {
        #   "" "";
        #   default "immutable";
        # }
        # JELLYFIN
        proxy_cache_path /var/cache/nginx/jellyfin-videos levels=1:2 keys_zone=jellyfin-videos:100m inactive=90d max_size=35000m;
        proxy_cache_path /var/cache/nginx/jellyfin levels=1:2 keys_zone=jellyfin:100m max_size=15g inactive=30d use_temp_path=off;
        map $request_uri $h264Level { ~(h264-level=)(.+?)& $2; }
        map $request_uri $h264Profile { ~(h264-profile=)(.+?)& $2; }
    '';
    virtualHosts = let
      base = locations: {
        inherit locations;
        forceSSL = true;
        enableACME = true;
        http2 = true;
      };
      proxy = port:
        base { "/".proxyPass = "http://${localhost}:${toString (port)}/"; };
      proxyArr = port:
        proxy port // {
          extraConfig = ''
            proxy_set_header   Host $host;
                proxy_set_header   X-Forwarded-For $proxy_add_x_forwarded_for;
                proxy_set_header   X-Forwarded-Host $host;
                proxy_set_header   X-Forwarded-Proto $scheme;
                proxy_set_header   Upgrade $http_upgrade;
                proxy_set_header   Connection $http_connection;

                proxy_redirect     off;
                proxy_http_version 1.1;
          '';
        };
    in {
      "movies.servidos.lat" = proxyArr radarrPort // { };
      "indexer.servidos.lat" = proxyArr prowlarrPort // { };
      "newflix.servidos.lat" = proxy newflixPort // { };
      "library.servidos.lat" = proxy kavitaPort // { };
      "bookmarks.servidos.lat" = proxy shioriPort // { };
      "start.servidos.lat" = proxy flamePort // { };
      "music.servidos.lat" = proxy lidarrPort // { };
      "subs.servidos.lat" = proxy bazarrPort // { };
      "series.servidos.lat" = proxy sonarrPort // { };
      "vault.servidos.lat" = proxy vaultPort // { };
      "searx.servidos.lat" = proxy searxPort // { };
      "qampqwn4wprhqny8h8zj.servidos.lat" = proxy secretFlamePort // { };
      "flix.servidos.lat" = {
        forceSSL = true;
        enableACME = true;
        http2 = true;
        extraConfig = ''
          # use a variable to store the upstream proxy
          # in this example we are using a hostname which is resolved via DNS
          # (if you aren't using DNS remove the resolver line and change the variable to point to an IP address
          resolver ${localhost} valid=30;

          location = / {
            return 302 http://$host/web/;
            #return 302 https://$host/web/;
          }
          location = /web/ {
            # Proxy main Jellyfin traffic
            proxy_pass http://${localhost}:${jellyfinPort}/web/index.html;
            proxy_set_header Host $host;
            proxy_set_header X-Real-IP $remote_addr;
            proxy_set_header X-Forwarded-For $proxy_add_x_forwarded_for;
            proxy_set_header X-Forwarded-Proto $scheme;
            proxy_set_header X-Forwarded-Protocol $scheme;
            proxy_set_header X-Forwarded-Host $http_host;
          }
        '';
        locations = {
          "/" = {
            proxyPass = "http://${localhost}:${jellyfinPort}";
            proxyWebsockets = true;
          };
          "/socket" = {
            proxyPass = "http://${localhost}:${jellyfinPort}";
            extraConfig = ''
              proxy_http_version 1.1;
              proxy_set_header Upgrade $http_upgrade;
              proxy_set_header Connection "upgrade";
            '';
          };
          "~ /Items/(.*)/Images" = {
            proxyPass = "http://${localhost}:${jellyfinPort}";
            extraConfig = ''
              proxy_cache jellyfin;
              proxy_cache_revalidate on;
              proxy_cache_lock on;
            '';
          };
          "~* ^/Videos/(.*)/(?!live)" = {
            proxyPass = "http://${localhost}:${jellyfinPort}";
            extraConfig = ''
              # Set size of a slice (this amount will be always requested from the backend by nginx)
              # Higher value means more latency, lower more overhead
              # This size is independent of the size clients/browsers can request
              # slice 2m;

              proxy_cache jellyfin-videos;
              proxy_cache_valid 200 206 301 302 30d;
              proxy_ignore_headers Expires Cache-Control Set-Cookie X-Accel-Expires;
              proxy_cache_use_stale error timeout invalid_header updating http_500 http_502 http_503 http_504;
              proxy_connect_timeout 15s;
              proxy_http_version 1.1;
              proxy_set_header Connection "";
              # Transmit slice range to the backend
              proxy_set_header Range 2m;

              # This saves bandwidth between the proxy and jellyfin, as a file is only downloaded one time instead of multiple times when multiple clients want to at the same time
              # The first client will trigger the download, the other clients will have to wait until the slice is cached
              # Esp. practical during SyncPlay
              proxy_cache_lock on;
              proxy_cache_lock_age 60s;

              proxy_cache_key "jellyvideo$uri?MediaSourceId=$arg_MediaSourceId&VideoCodec=$arg_VideoCodec&AudioCodec=$arg_AudioCodec&AudioStreamIndex=$arg_AudioStreamIndex&VideoBitrate=$arg_VideoBitrate&AudioBitrate=$arg_AudioBitrate&SubtitleMethod=$arg_SubtitleMethod&TranscodingMaxAudioChannels=$arg_TranscodingMaxAudioChannels&RequireAvc=$arg_RequireAvc&SegmentContainer=$arg_SegmentContainer&MinSegments=$arg_MinSegments&BreakOnNonKeyFrames=$arg_BreakOnNonKeyFrames&h264-profile=$h264Profile&h264-level=$h264Level&slicerange=2m";

              # add_header X-Cache-Status $upstream_cache_status; # This is only for debugging cache
            '';
          };
        };
      };
      ${config.services.nextcloud.hostName} = {
        forceSSL = true;
        enableACME = true;
        http2 = true;
        serverAliases = [ "cloud.rotehaare.art" "danilo-reyes.com" ];
      };
    };
  };
  networking = {
    firewall = let open_firewall_ports = [ 80 443 ];
    in {
      enable = true;
      allowedTCPPorts = open_firewall_ports;
      allowedUDPPorts = open_firewall_ports;
    };
  };
}