{
  description = "JawZ NixOS flake setup";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nix-gaming.url = "github:fufexan/nix-gaming";
    hyprland.url = "github:hyprwm/Hyprland";
    sops-nix = {
      url = "github:Mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixos-cosmic = {
      url = "github:lilyinstarlight/nixos-cosmic";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    zen-browser.url = "github:MarceColl/zen-browser-flake";
  };

  outputs =
    {
      self,
      nixpkgs,
      home-manager,
      sops-nix,
      nixos-cosmic,
      ...
    }@inputs:
    let
      inherit (self) outputs;
      lib = nixpkgs.lib // home-manager.lib;
      system = "x86_64-linux";
      makePkgs =
        repo:
        import repo {
          inherit system;
          config.allowUnfree = true;
        };
      pkgs = makePkgs nixpkgs;
      overlays = [ (import ./overlay.nix { inherit pkgs; }) ];
      createConfig = name: {
        inherit system;
        specialArgs = {
          inherit inputs outputs;
        };
        modules = [
          (_: { nixpkgs.overlays = overlays; })
          ./hosts/${name}/configuration.nix
          sops-nix.nixosModules.sops
          nixos-cosmic.nixosModules.default
        ];
      };
    in
    {
      inherit lib pkgs;
      formatter = pkgs.alejandra;
      nixosConfigurations = {
        workstation = lib.nixosSystem (createConfig "workstation");
        miniserver = lib.nixosSystem (createConfig "miniserver");
        server = lib.nixosSystem (createConfig "server");
      };
    };
}