# Do not modify this file!  It was generated by ‘nixos-generate-config’

# and may be overwritten by future invocations.  Please make changes
# to /etc/nixos/configuration.nix instead.
{ config, lib, pkgs, modulesPath, ... }:
let
  localhost = "127.0.0.1";
  workstation = "192.168.1.64";
  domain = "servidos.lat";
  jellyfinPort = 8096;
  nextcloudPort = 80;
  collaboraPort = 9980;
  flamePort = 5005;
  secretFlamePort = 5007;
  lidarrPort = 8686;
  qbitPort = 9091;
  prowlarrPort = 9696;
  radarrPort = 7878;
  sonarrPort = 8989;
  mealiePort = 9925;
  ryotPort = 8765;
  scrobblePort = 9078;
  malojaPort = 42010;
  darkwirePort = 3001;
  jiraPort = 8091;
  metatubePort = 8881;
  bazarrPort = config.services.bazarr.listenPort;
  kavitaPort = config.services.kavita.port;
  vaultPort = config.services.vaultwarden.config.ROCKET_PORT;
  audiobookPort = config.services.audiobookshelf.port;
  microbinPort = config.services.microbin.settings.MICROBIN_PORT;
in {
  services.nginx = {
    enable = true;
    clientMaxBodySize = "4096m";
    # recommendedTlsSettings = true;
    # recommendedGzipSettings = true;
    # recommendedOptimisation = true;
    sslCiphers = "AES256+EECDH:AES256+EDH:!aNULL";
    appendHttpConfig = ''
      # JELLYFIN
      proxy_cache_path /var/cache/nginx/jellyfin-videos levels=1:2 keys_zone=jellyfin-videos:100m inactive=90d max_size=35000m;
      proxy_cache_path /var/cache/nginx/jellyfin levels=1:2 keys_zone=jellyfin:100m max_size=15g inactive=30d use_temp_path=off;
      map $request_uri $h264Level { ~(h264-level=)(.+?)& $2; }
      map $request_uri $h264Profile { ~(h264-profile=)(.+?)& $2; }
    '';
    virtualHosts = let
      base = locations: {
        inherit locations;
        forceSSL = true;
        enableACME = true;
        http2 = true;
      };
      proxy = port:
        base { "/".proxyPass = "http://${localhost}:${toString (port)}/"; };
      proxyArr = port:
        proxy port // {
          extraConfig = ''
            proxy_set_header   Host $host;
            proxy_set_header   X-Forwarded-For $proxy_add_x_forwarded_for;
            proxy_set_header   X-Forwarded-Host $host;
            proxy_set_header   X-Forwarded-Proto $scheme;
            proxy_set_header   Upgrade $http_upgrade;
            proxy_set_header   Connection $http_connection;

            proxy_redirect     off;
            proxy_http_version 1.1;
          '';
        };
    in {
      # "movies.${domain}" = proxyArr radarrPort // { };
      # "indexer.${domain}" = proxyArr prowlarrPort // { };
      # "music.${domain}" = proxyArr lidarrPort // { };
      # "library.${domain}" = proxy kavitaPort // { };
      "start.${domain}" = proxy flamePort // { };
      # "subs.${domain}" = proxy bazarrPort // { };
      # "series.${domain}" = proxy sonarrPort // { };
      "vault.${domain}" = proxy vaultPort // { };
      "copy.${domain}" = proxy microbinPort // { };
      "mealie.${domain}" = proxy mealiePort // { };
      "tracker.${domain}" = proxy ryotPort // { };
      "scrobble.${domain}" = proxy scrobblePort // { };
      "maloja.${domain}" = proxy malojaPort // { };
      "jira.${domain}" = proxy jiraPort // { };
      "bajameesta.${domain}" = proxy metatubePort // { };
      "qampqwn4wprhqny8h8zj.${domain}" = proxy secretFlamePort // { };
      "xfwmrle6h6skqujbeizw.${domain}" = proxy qbitPort // { };
      "audiobooks.${domain}" = base {
        "/" = {
          proxyPass = "http://${localhost}:${toString (audiobookPort)}";
          extraConfig = ''
            proxy_set_header X-Forwarded-For   $proxy_add_x_forwarded_for;
            proxy_set_header X-Forwarded-Proto $scheme;
            proxy_set_header Host              $host;
            proxy_set_header Upgrade           $http_upgrade;
            proxy_set_header Connection        "upgrade";

            proxy_http_version                  1.1;

            proxy_redirect                      http:// https://;
          '';
        };
      };
      "dontcancelmeplz.${domain}" = base {
        "/" = {
          proxyPass = "http://${localhost}:${toString (darkwirePort)}";
          proxyWebsockets = true;
          extraConfig = ''
            # Ensuring it can use websockets
            proxy_set_header   Upgrade $http_upgrade;
            proxy_set_header   Connection "upgrade";
            proxy_set_header   X-Real-IP $remote_addr;
            proxy_set_header   X-Forwarded-For $proxy_add_x_forwarded_for;
            proxy_set_header   X-Forwarded-Proto http;
            proxy_redirect     http:// $scheme://;

            # The proxy must preserve the host because gotify verifies the host with the origin
            # for WebSocket connections
            proxy_set_header   Host $host;

            # These sets the timeout so that the websocket can stay alive
            proxy_connect_timeout   1m;
            proxy_send_timeout      1m;
            proxy_read_timeout      1m;
          '';
        };
      };
      "flix.${domain}" = {
        forceSSL = true;
        enableACME = true;
        http2 = true;
        extraConfig = ''
          # use a variable to store the upstream proxy
          # in this example we are using a hostname which is resolved via DNS
          # (if you aren't using DNS remove the resolver line and change the variable to point to an IP address
          resolver ${localhost} valid=30;

          location = / {
            return 302 http://$host/web/;
            #return 302 https://$host/web/;
          }

          location = /web/ {
            # Proxy main Jellyfin traffic
            proxy_pass http://${localhost}:${
              toString (jellyfinPort)
            }/web/index.html;
            proxy_set_header Host $host;
            proxy_set_header X-Real-IP $remote_addr;
            proxy_set_header X-Forwarded-For $proxy_add_x_forwarded_for;
            proxy_set_header X-Forwarded-Proto $scheme;
            proxy_set_header X-Forwarded-Protocol $scheme;
            proxy_set_header X-Forwarded-Host $http_host;
          }
        '';
        locations = {
          "/" = {
            proxyPass = "http://${localhost}:${toString (jellyfinPort)}";
            proxyWebsockets = true;
          };
          "/socket" = {
            proxyPass = "http://${localhost}:${toString (jellyfinPort)}";
            extraConfig = ''
              proxy_http_version 1.1;
              proxy_set_header Upgrade $http_upgrade;
              proxy_set_header Connection "upgrade";
            '';
          };
          "~ /Items/(.*)/Images" = {
            proxyPass = "http://${localhost}:${toString (jellyfinPort)}";
            extraConfig = ''
              proxy_cache jellyfin;
              proxy_cache_revalidate on;
              proxy_cache_lock on;
            '';
          };
          "~* ^/Videos/(.*)/(?!live)" = {
            proxyPass = "http://${localhost}:${toString (jellyfinPort)}";
            extraConfig = ''
              # Set size of a slice (this amount will be always requested from the backend by nginx)
              # Higher value means more latency, lower more overhead
              # This size is independent of the size clients/browsers can request
              # slice 2m;

              proxy_cache jellyfin-videos;
              proxy_cache_valid 200 206 301 302 30d;
              proxy_ignore_headers Expires Cache-Control Set-Cookie X-Accel-Expires;
              proxy_cache_use_stale error timeout invalid_header updating http_500 http_502 http_503 http_504;
              proxy_connect_timeout 15s;
              proxy_http_version 1.1;
              proxy_set_header Connection "";
              # Transmit slice range to the backend
              proxy_set_header Range 2m;

              # This saves bandwidth between the proxy and jellyfin, as a file is only downloaded one time instead of multiple times when multiple clients want to at the same time
              # The first client will trigger the download, the other clients will have to wait until the slice is cached
              # Esp. practical during SyncPlay
              proxy_cache_lock on;
              proxy_cache_lock_age 60s;

              proxy_cache_key "jellyvideo$uri?MediaSourceId=$arg_MediaSourceId&VideoCodec=$arg_VideoCodec&AudioCodec=$arg_AudioCodec&AudioStreamIndex=$arg_AudioStreamIndex&VideoBitrate=$arg_VideoBitrate&AudioBitrate=$arg_AudioBitrate&SubtitleMethod=$arg_SubtitleMethod&TranscodingMaxAudioChannels=$arg_TranscodingMaxAudioChannels&RequireAvc=$arg_RequireAvc&SegmentContainer=$arg_SegmentContainer&MinSegments=$arg_MinSegments&BreakOnNonKeyFrames=$arg_BreakOnNonKeyFrames&h264-profile=$h264Profile&h264-level=$h264Level&slicerange=2m";

              # add_header X-Cache-Status $upstream_cache_status; # This is only for debugging cache
            '';
          };
        };
      };
      # ${config.services.nextcloud.hostName} = {
      #   forceSSL = true;
      #   enableACME = true;
      #   http2 = true;
      #   serverAliases = [ "cloud.rotehaare.art" ];
      #   locations = {
      #     "/".proxyWebsockets = true;
      #     # uh, equals what?
      #     "~ ^/nextcloud/(?:index|remote|public|cron|core/ajax/update|status|ocs/v[12]|updater/.+|oc[ms]-provider/.+|.+/richdocumentscode/proxy).php(?:$|/)" =
      #       { };
      #   };
      # };

      # "collabora.${domain}" = let
      #   collaboraString = "http://${localhost}:${toString (collaboraPort)}";
      #   collaboraProxy = {
      #     proxyPass = collaboraString;
      #     extraConfig = ''
      #       proxy_set_header Host $host;
      #     '';
      #   };
      #   collaboraSocket = {
      #     proxyPass = collaboraString;
      #     extraConfig = ''
      #       proxy_set_header Upgrade $http_upgrade;
      #       proxy_set_header Connection "Upgrade";
      #       proxy_set_header Host $host;
      #       proxy_read_timeout 36000s;
      #     '';
      #   };
      # in base {
      #   # static files
      #   "^~ /loleaflet" = collaboraProxy;
      #   # WOPI discovery URL
      #   "^~ /hosting/discovery" = collaboraProxy;
      #   # Capabilities
      #   "^~ /hosting/capabilities" = collaboraProxy;
      #   # download, presentation, image upload and websocket
      #   "~ ^/lool" = collaboraSocket;
      #   # Admin Console websocket
      #   "^~ /lool/adminws" = collaboraSocket;
      # };
    };
  };
  networking = {
    firewall = let open_firewall_ports = [ 80 443 ];
    in {
      enable = true;
      allowedTCPPorts = open_firewall_ports;
      allowedUDPPorts = open_firewall_ports;
    };
  };
}