{ pkgs }:
_self: super: {
  gnome = super.gnome.overrideScope (
    _gFinal: gPrev: {
      nautilus = gPrev.nautilus.overrideAttrs (nsuper: {
        buildInputs =
          nsuper.buildInputs
          ++ builtins.attrValues {
            inherit (pkgs.gst_all_1)
              gst-plugins-good
              gst-plugins-bad
              ;
          };
      });
    }
  );
  lutris = super.lutris.override {
    extraPkgs =
      pkgs:
      let
        corePackages = builtins.attrValues {
          inherit (pkgs) pango winetricks;
        };
        winePackages = [
          pkgs.wine64Packages.stable
          pkgs.wineWowPackages.stable
        ];
      in
      corePackages ++ winePackages;
  };
  handbrake = super.handbrake.override { useGtk = true; };
  discord-ptb = super.discord.override { withVencord = true; };
  ripgrep = super.ripgrep.override { withPCRE2 = true; };
  papirus-icon-theme = super.papirus-icon-theme.override { color = "yellow"; };
  blender = super.blender.override { cudaSupport = true; };
}