NixOS/hosts/workstation/configuration.nix

{ config, lib, pkgs, ... }:
let
  unstable = import
    (builtins.fetchTarball "https://github.com/nixos/nixpkgs/tarball/master") {
      config = config.nixpkgs.config;
    };
in {
  imports = [
    # <agenix/modules/age.nix>
    ./hardware-configuration.nix
    ../../base.nix
    ../../gnome.nix
    ../../home-manager/default.nix
    # ../../services/systemd-user/tasks.nix
  ];
  my = {
    emacs.enable = true;
    apps = {
      art.enable = true;
      dictionaries.enable = true;
      fonts.enable = true;
      gaming.enable = true;
      internet.enable = true;
      multimedia.enable = true;
      office.enable = true;
    };
    dev = {
      haskell.enable = true;
      nix.enable = true;
      python.enable = true;
      gameDev.enable = true;
    };
    shell = { exercism.enable = true; };
    services = {
      network.enable = true;
      nvidia.enable = true;
      printing.enable = true;
      sound.enable = true;
    };
  };

  networking = {
    hostName = "workstation";
    firewall = let
      openPorts = [
        7860 # chatgpt
        6674 # ns-usbloader
      ];
      openPortRanges = [{
        from = 1714; # kdeconnect
        to = 1764; # kdeconnect
      }];
    in {
      allowedTCPPorts = openPorts;
      allowedUDPPorts = openPorts;
      allowedTCPPortRanges = openPortRanges;
      allowedUDPPortRanges = openPortRanges;
    };
  };
  nix = let
    featuresList = [
      "nixos-test"
      "benchmark"
      "big-parallel"
      "kvm"
      "gccarch-znver3"
      "gccarch-skylake"
      "gccarch-alderlake"
    ];
  in {
    distributedBuilds = true;
    settings = {
      cores = 16;
      trusted-users = [ "nixremote" ];
      system-features = featuresList;
    };
  };

  nixpkgs = {
    config = {
      allowUnfree = true;
      permittedInsecurePackages = [ ];
    };
  };

  users = {
    groups.nixremote.gid = 555;
    users = {
      nixremote = {
        isNormalUser = true;
        createHome = true;
        group = "nixremote";
        home = "/var/nixremote/";
        openssh.authorizedKeys.keys = [
          "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIN6HsajaTL+nTJtSIu00M5WJwgt/7fyU59gBr2R7tbnv root@server"
          "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIGrC7sVvDT0is2oq/H1Do99LPaQKvyGMAsrF6/fuf1aP root@miniserver"
        ];
      };
      jawz = {
        packages = (with pkgs; [
          obs-studio # screen recorder & streamer
          pitivi # video editor
          gocryptfs # encrypted filesystem! shhh!!!

          # celeste # sync tool for any cloud provider
          # czkawka # duplicate finder
          # sequeler # friendly SQL client
          blanket # background noise
          metadata-cleaner # remove any metadata and geolocation from files
          pika-backup # backups
          gnome-obfuscate # censor private information

          (ripgrep.override { withPCRE2 = true; }) # modern grep
          du-dust # rusty du similar to gdu
          eza # like ls but with colors
          fd # modern find, faster searches
          ffmpeg # not ffmpreg, the coolest video conversion tool!
          fzf # fuzzy finder! super cool and useful
          gallery-dl # similar to yt-dlp but for most image gallery websites
          gdu # disk-space utility checker, somewhat useful
          imagemagick # photoshop what??
          rmlint # probably my favourite app, amazing dupe finder that integrates well with BTRFS
          tldr # man for retards
          trash-cli # oop! did not meant to delete that
          yt-dlp # downloads videos from most video websites

          torrenttools # create torrent files from the terminal!
          vcsi # video thumbnails for torrents, can I replace it with ^?

          (writeScriptBin "tasks" (builtins.readFile ../../scripts/tasks.sh))
          (writeScriptBin "ffmpeg4discord"
            (builtins.readFile ../../scripts/ffmpeg4discord.py))
          (writeScriptBin "ffmpreg"
            (builtins.readFile ../../scripts/ffmpreg.sh))
          (writeScriptBin "split-dir"
            (builtins.readFile ../../scripts/split-dir.sh))
          (writeScriptBin "run" (builtins.readFile ../../scripts/run.sh))
          (writeScriptBin "pika-list"
            (builtins.readFile ../../scripts/pika-list.sh))

          # required (optionally) by doom emacs, but still are rather useful
          tree-sitter # code parsing based on symbols and shit, I do not get it
          graphviz # graphs
          tetex
          languagetool # proofreader for English
          # these two are for doom everywhere
          xorg.xwininfo
          xdotool
          xclip

          # SH
          bashdb # autocomplete
          shellcheck # linting
          shfmt # a shell parser and formatter

          # DOCKER
          dockfmt

          # JS
          nodejs # not as bad as I thought
          jq # linting

        ]) ++ (with pkgs.python3Packages; [
          (buildPythonApplication rec {
            pname = "download";
            version = "1.5";
            src = ../../scripts/download/.;
            doCheck = false;
            buildInputs = [ setuptools ];
            propagatedBuildInputs = [ pyyaml types-pyyaml ];
          })
          (buildPythonApplication rec {
            pname = "ffpb";
            version = "0.4.1";
            src = fetchPypi {
              inherit pname version;
              sha256 = "sha256-7eVqbLpMHS1sBw2vYS4cTtyVdnnknGtEI8190VlXflk=";
            };
            doCheck = false;
            buildInputs = [ setuptools ];
            propagatedBuildInputs = [ tqdm ];
          })

        ]) ++ (with pkgs.nodePackages; [
          # Language servers
          dockerfile-language-server-nodejs
          yaml-language-server
          bash-language-server
          vscode-json-languageserver
          pyright

          markdownlint-cli # Linter
          prettier # Linter
          pnpm # Package manager
        ]);
      }; # <--- end of package list
    };
  };

  environment.etc = {
    "wireplumber/bluetooth.lua.d/51-bluez-config.lua".text = ''
      bluez_monitor.properties = {
          ["bluez5.enable-sbc-xq"] = true,
          ["bluez5.enable-msbc"] = true,
          ["bluez5.enable-hw-volume"] = true,
          ["bluez5.headset-roles"] = "[ hsp_hs hsp_ag hfp_hf hfp_ag ]"
      }
    '';
  };

  programs.kdeconnect = {
    enable = true;
    package = pkgs.gnomeExtensions.gsconnect;
  };

  # programs.nh = {
  #   enable = true;
  #   clean.enable = true;
  #   clean.extraArgs = "--keep-since 4d --keep 3";
  # };

  services.resilio = {
    deviceName = "chichis";
    enable = true;
    useUpnp = true;
    enableWebUI = true;
    httpPass = "528491";
    httpLogin = "chichis";
    httpListenPort = 9876;
    httpListenAddr = "0.0.0.0";
    directoryRoot = "/resilio";
  };
}