organized pkgs by packaging tests and awaiting pr

2024-12-15 00:28:06 -06:00
parent 7e658479f8
commit 850550ae9a
7 changed files with 82 additions and 1 deletions
--- a/pkgs_pr/talk.nix
+++ b/pkgs_pr/talk.nix
@@ -0,0 +1,89 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+  autoPatchelfHook,
+  nss,
+  cairo,
+  xorg,
+  libxkbcommon,
+  alsa-lib,
+  at-spi2-core,
+  mesa,
+  pango,
+  libdrm,
+  vivaldi-ffmpeg-codecs,
+  gtk3,
+  libGL,
+  libglvnd,
+  systemd,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "nextcloud-talk-desktop";
+  version = "1.0.0";
+
+  # Building from source would require building also building Server and Talk components
+  # See https://github.com/nextcloud/talk-desktop?tab=readme-ov-file#%EF%B8%8F-prerequisites
+  src = fetchzip {
+    url = "https://github.com/nextcloud-releases/talk-desktop/releases/download/v${finalAttrs.version}/Nextcloud.Talk-linux-x64.zip";
+    hash = "sha256-XQa4Fa9eEaFlYrWa00S9aMWKJOPPFGSo4NAlRqE23jM=";
+    stripRoot = false;
+  };
+
+  nativeBuildInputs = [ autoPatchelfHook ];
+
+  buildInputs =
+    [
+      nss
+      cairo
+      alsa-lib
+      at-spi2-core
+      pango
+      libdrm
+      libxkbcommon
+      gtk3
+      vivaldi-ffmpeg-codecs
+      mesa
+      libGL
+      libglvnd
+    ]
+    ++ (with xorg; [
+      libX11
+      libXcomposite
+      libXdamage
+      libXrandr
+      libXfixes
+      libXcursor
+    ]);
+
+  # Required to launch the application and proceed past the zygote_linux fork() process
+  # Fixes `Zygote could not fork`
+  runtimeDependencies = [ systemd ];
+
+  preInstall = ''
+    mkdir -p $out/bin
+    mkdir -p $out/opt
+
+    cp -r $src/* $out/opt/
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    # Link the application in $out/bin away from contents of `preInstall`
+    ln -s "$out/opt/Nextcloud Talk-linux-x64/Nextcloud Talk" $out/bin/nextcloud-talk-desktop
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Nextcloud Talk Desktop Client";
+    homepage = "https://github.com/nextcloud/talk-desktop";
+    changelog = "https://github.com/nextcloud/talk-desktop/blob/${finalAttrs.version}/CHANGELOG.md";
+    license = licenses.agpl3Only;
+    maintainers = with maintainers; [ kashw2 ];
+    mainProgram = "nextcloud-talk-desktop";
+    sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
+  };
+})
--- a/pkgs_pr/webcomix.nix
+++ b/pkgs_pr/webcomix.nix
@@ -0,0 +1,53 @@
+{
+  lib,
+  fetchFromGitHub,
+  python3Packages,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "webcomix";
+  version = "3.11.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "J-CPelletier";
+    repo = "webcomix";
+    rev = version;
+    hash = "sha256-Y16+/9TnECMkppgI/BeAbTLWt0M4V/xn1+hM4ILp/+g=";
+  };
+
+  postPatch = ''
+    substituteInPlace pyproject.toml \
+      --replace-fail "poetry>=1.2.0" poetry-core \
+      --replace-fail "poetry.masonry.api" "poetry.core.masonry.api" \
+      --replace-fail 'pytest-rerunfailures = "^11.1.2"' 'pytest-rerunfailures = "14.0"'
+  '';
+
+  build-system = [
+    python3Packages.poetry-core
+  ];
+
+  dependencies = with python3Packages; [
+    click
+    tqdm
+    scrapy
+    scrapy-splash
+    scrapy-fake-useragent
+    pytest-rerunfailures
+    docker
+  ];
+
+  preCheck = ''
+    export HOME=$(mktemp -d)
+  '';
+
+  doCheck = false;
+
+  meta = {
+    description = "Webcomic downloader";
+    homepage = "https://github.com/J-CPelletier/webcomix";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ CaptainJawZ ];
+    mainProgram = "webcomix";
+  };
+}